delphi Windows 编程[17] - 更换菜单: LoadMenu、DestroyMenu、SetMenu


本文整理自网络,侵删。

 
Windows 编程[17] - 更换菜单: LoadMenu、DestroyMenu、SetMenu
本例效果图:



本例在资源文件中备有两组菜单, 程序实现运行时切换.

本例使用的资源文件(TestRes.rc):
MyMenu1 MENUEX
BEGIN
  MENUITEM "Open"    ,101
  MENUITEM "Edit"    ,102
  MENUITEM "Help"    ,103
  MENUITEM "Chinese" ,104 ,MFT_RIGHTJUSTIFY
END

MyMenu2 MENUEX
BEGIN
  MENUITEM "打开"    ,201
  MENUITEM "编辑"    ,202
  MENUITEM "帮助"    ,203
  MENUITEM "English" ,204 ,MFT_RIGHTJUSTIFY
END

本例代码文件:
program Project1;

{$R 'TestRes.res' 'TestRes.rc'}

uses
  Windows, Messages;

{收到 WM_COMMAND 消息时需要做的工作}
procedure OnCommand(h: HWND; wParam: Integer);
var
  hm : HMENU;
begin
  case wParam of
    104,204: begin   {104 和 204 是在资源文件中指定的菜单标识}
      if LoWord(wParam) = 104 then
        hm := LoadMenu(HInstance, 'MyMenu2')
      else
        hm := LoadMenu(HInstance, 'MyMenu1');
      DestroyMenu(GetMenu(h));
      SetMenu(h, hm);
      DrawMenuBar(h);
    end;
  end;
end;

function WndProc(wnd: HWND; msg: UINT; wParam: Integer; lParam: Integer): Integer; stdcall;
begin
  Result := 0;
  case msg of
    WM_COMMAND : OnCommand(wnd, wParam); {收到 WM_COMMAND 消息后调用 OnCommand 过程}
    WM_DESTROY : PostQuitMessage(0);
  else
    Result := DefWindowProc(wnd, msg, wParam, lParam);
  end;
end;

function RegMyWndClass: Boolean;
var
  cls: TWndClass;
begin
  cls.style         := CS_HREDRAW or CS_VREDRAW;
  cls.lpfnWndProc   := @WndProc;
  cls.cbClsExtra    := 0;
  cls.cbWndExtra    := 0;
  cls.hInstance     := HInstance;
  cls.hIcon         := 0;
  cls.hCursor       := LoadCursor(0, IDC_ARROW);
  cls.hbrBackground := HBRUSH(COLOR_WINDOW + 1);
  cls.lpszMenuName  := 'MyMenu1';
  cls.lpszClassName := 'MyWnd';
  Result := RegisterClass(cls) <> 0;
end;

{程序入口}
const
  tit = 'New Form';
  ws = WS_OVERLAPPEDWINDOW;
  x = 100; y = 100; w = 300; h = 180;
var
  hWnd: THandle;
  Msg : TMsg;
begin
  RegMyWndClass;
  hWnd := CreateWindow('MyWnd', tit, ws, x, y, w, h, 0, 0, HInstance, nil);
  ShowWindow(hWnd, SW_SHOWNORMAL);
  UpdateWindow(hWnd);

  while(GetMessage(Msg, 0, 0, 0)) do
  begin
    TranslateMessage(Msg);
    DispatchMessage(Msg);
  end;
end.

相关阅读 >>

Delphi 调用系统图片查看器

Delphi 隐藏任务栏程序,取消自动对齐和网格对齐

Delphi console程序中一种定时方法

Delphi datamodule1 fdconnection1数据库连接

Delphi中对url进行编码和解码

Delphi 用 tbytesstream 类实现的读文件为十六进制字符的函数

Delphi 完全自定义窗体风格的实现

Delphi app如何禁掉安卓锁屏

Delphi 小数点四舍五入问题

Delphi 数值小数点后不保留0

更多相关阅读请进入《Delphi》频道 >>



打赏

取消

感谢您的支持,我会继续努力的!

扫码支持
扫码打赏,您说多少就多少

打开支付宝扫一扫,即可进行扫码打赏哦

分享从这里开始,精彩与您同在

评论

管理员已关闭评论功能...