Oracle例外用法实例详解-木庄网络博客

本文整理自网络，侵删。

本文实例讲述了Oracle例外用法。分享给大家供大家参考，具体如下：

一、例外分类

oracle将例外分为预定义例外、非预定义例外和自定义例外三种。

1)、预定义例外用于处理常见的oracle错误。

2)、非预定义例外用于处理预定义例外不能处理的例外。

3)、自定义例外用于处理与oracle错误无关的其它情况。

下面通过一个小案例演示如果不处理例外看会出现什么情况？

编写一个存储过程，可接收雇员的编号，并显示该雇员的姓名。

sql代码如下：

SET SERVEROUTPUT ON;
DECLARE
 V_ENAME EMP.ENAME%TYPE;
BEGIN
 SELECT ENAME INTO V_ENAME FROM EMP WHERE EMPNO = &GNO;
 DBMS_OUTPUT.PUT_LINE('名字：' || V_ENAME);
END;
/

随便输入不存在的编号，回车，会抛出如下异常：

ORA-01403: 未找到数据
ORA-06512: 在line 6

例外捕获的sql代码如下：

SET SERVEROUTPUT ON;
DECLARE
 V_ENAME EMP.ENAME%TYPE;
BEGIN
 SELECT ENAME INTO V_ENAME FROM EMP WHERE EMPNO = &GNO;
 DBMS_OUTPUT.PUT_LINE('名字：' || V_ENAME);
EXCEPTION
 WHEN no_data_found THEN
  DBMS_OUTPUT.PUT_LINE('编号未找到！');
END;
/

随便输入不存在的编号，回车，会友情提示：编号未找到！

二、处理预定义例外

预定义例外是由pl/sql所提供的系统例外。当pl/sql应用程序违反了oracle规定的限制时，则会隐含的触发一个内部例外。pl/sql为开发人员提供了二十多个预定义例外。我们给大家介绍常用的例外。

1)、case_not_found预定义例外

在开发pl/sql块中编写case语句时，如果在when子句中没有包含必须的条件分支，就会触发case_not_found例外：

SET SERVEROUTPUT ON;
CREATE OR REPLACE PROCEDURE SP_PRO6(SPNO NUMBER) IS
 V_SAL EMP.SAL%TYPE;
BEGIN
 SELECT SAL INTO V_SAL FROM EMP WHERE EMPNO = SPNO;
 CASE
  WHEN V_SAL < 1000 THEN
   UPDATE EMP SET SAL = SAL + 100 WHERE EMPNO = SPNO;
  WHEN V_SAL < 2000 THEN
   UPDATE EMP SET SAL = SAL + 200 WHERE EMPNO = SPNO;
 END CASE;
EXCEPTION
 WHEN CASE_NOT_FOUND THEN
  DBMS_OUTPUT.PUT_LINE('case语句没有与' || V_SAL || '相匹配的条件');
END;
/
--调用存储过程
SQL> EXEC SP_PRO6(7369);

case语句没有与4444相匹配的条件

2)、cursor_already_open预定义例外

当重新打开已经打开的游标时，会隐含的触发cursor_already_open例外

DECLARE
 CURSOR EMP_CURSOR IS
  SELECT ENAME, SAL FROM EMP;
BEGIN
 OPEN EMP_CURSOR; --声明时游标已打开，所以没必要再次打开
 FOR EMP_RECORD1 IN EMP_CURSOR LOOP
  DBMS_OUTPUT.PUT_LINE(EMP_RECORD1.ENAME);
 END LOOP;
EXCEPTION
 WHEN CURSOR_ALREADY_OPEN THEN
  DBMS_OUTPUT.PUT_LINE('游标已经打开');
END;
/

3)、dup_val_on_index预定义例外

在唯一索引所对应的列上插入重复的值时，会隐含的触发例外

BEGIN
 INSERT INTO DEPT VALUES (10, '公关部', '北京');
EXCEPTION
 WHEN DUP_VAL_ON_INDEX THEN
  DBMS_OUTPUT.PUT_LINE('在deptno列上不能出现重复值');
END;
/

4)、invalid_cursorn预定义例外

当试图在不合法的游标上执行操作时，会触发该例外

例如：试图从没有打开的游标提取数据，或是关闭没有打开的游标。则会触发该例外

DECLARE
 CURSOR EMP_CURSOR IS
  SELECT ENAME, SAL FROM EMP;
 EMP_RECORD EMP_CURSOR%ROWTYPE;
BEGIN
 --open emp_cursor; --打开游标
 FETCH EMP_CURSOR INTO EMP_RECORD;
 DBMS_OUTPUT.PUT_LINE(EMP_RECORD.ENAME);
 CLOSE EMP_CURSOR;
EXCEPTION
 WHEN INVALID_CURSOR THEN
  DBMS_OUTPUT.PUT_LINE('请检测游标是否打开');
END;
/

5)、invalid_number预定义例外

阅读剩余部分